     FOR I=1 TO UM                                         ' INICIALIZA VENTAS X MESERO
         GET#2,I                                           ' accesa
         VD$=VD2$                                          ' ventas
         MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         VU$=VU2$                                          ' venta en unidades
         MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CI$=CI2$                                          ' cancelaciones
         MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CU$=CU2$                                          ' cancel en unidades
         MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         NP$=NP2$                                          ' personas
         MID$(NP$, 62*(MES-1)+2*(DIA-1)+1,2)=MKI$(0)       ' asigna
         NC$=NC2$                                          ' cuentas
         MID$(NC$, 62*(MES-1)+2*(DIA-1)+1,2)=MKI$(0)       ' asigna
         LSET VD2$=VD$                                     ' ventas importe
         LSET VU2$=VU$                                     ' ventas unidad
         LSET CI2$=CI$                                     ' cancel importe
         LSET CU2$=CU$                                     ' cancel unidad
         LSET NP2$=NP$                                     ' personas
         LSET NC2$=NC$                                     ' cuentas
         PUT#2,I                                           ' graba
     NEXT I

     FOR I=1 TO UP                                         ' INICIALIZA VENTAS X PLU
         GET#3,I                                           ' accesa
         VD$=VD3$                                          ' ventas
         MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         VU$=VU3$                                          ' venta en unidades
         MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CI$=CI3$                                          ' cancelaciones
         MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CU$=CU3$                                          ' cancel en unidades
         MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         LSET VD3$=VD$                                     ' ventas importe
         LSET VU3$=VU$                                     ' ventas unidad
         LSET CI3$=CI$                                     ' cancel importe
         LSET CU3$=CU$                                     ' cancel unidad
         PUT#3,I                                           ' graba
     NEXT I

     FOR I=1 TO 24                                         ' INICIALIZA VENTAS X HORA
         GET#4,I                                           ' accesa
         VD$=VD4$                                          ' ventas
         MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         VU$=VU4$                                          ' venta en unidades
         MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CI$=CI4$                                          ' cancelaciones
         MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         CU$=CU4$                                          ' cancel en unidades
         MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(0)       ' asigna
         NP$=NP4$                                          ' personas
         MID$(NP$, 62*(MES-1)+2*(DIA-1)+1,2)=MKI$(0)       ' asigna
         NC$=NC4$                                          ' cuentas
         MID$(NC$, 62*(MES-1)+2*(DIA-1)+1,2)=MKI$(0)       ' asigna
         NT$=NT4$                                          ' notas
         MID$(NT$, 62*(MES-1)+2*(DIA-1)+1,2)=MKI$(0)       ' asigna
         LSET VD4$=VD$                                     ' ventas importe
         LSET VU4$=VU$                                     ' ventas unidad
         LSET CI4$=CI$                                     ' cancel importe
         LSET CU4$=CU$                                     ' cancel unidad
         LSET NP4$=NP$                                     ' personas
         LSET NC4$=NC$                                     ' cuentas
         LSET NT4$=NT$                                     ' notas
         PUT#4,I                                           ' graba
     NEXT I

     V36$=SPACE$(36)
     FOR I=1 TO 9
         MID$(V36$,4*(I-1)+1,4)=MKS$(0)
     NEXT I
     V32$=SPACE$(32)
     FOR I=1 TO 8
         MID$(V32$,4*(I-1)+1,4)=MKS$(0)
     NEXT I
     V18$=SPACE$(18)
     FOR I=1 TO 9
         MID$(V18$,2*(I-1)+1,2)=MKI$(0)
     NEXT I
     V16$=SPACE$(16)
     FOR I=1 TO 8
         MID$(V16$,2*(I-1)+1,2)=MKI$(0)
     NEXT I

     FOR I=1 TO 24                                         ' INICIALIZA VENTAS X HORA 2
         RHOR=372*(I-1)+MESDIA
         GET#6,RHOR                                        ' accesa
         LSET VDL6$=V36$                                   ' vector de ventas en importe por localizacion
         LSET VUL6$=V18$                                   ' vector de ventas en unidades por localizacion
         LSET VDC6$=V32$                                   ' vector de ventas en importe por categoria  
         LSET VUC6$=V16$                                   ' vector de ventas en unidades por categoria
         LSET DI6$=SPACE$(26)                              ' disponible
         PUT#6,RHOR
     NEXT I

     FOR RL=1 TO 9                                         ' INICIA LOCALIZACIONES
         FOR RC=1 TO 8                                     ' categorias
             VLC#(RL,RC)=0                                 ' ventas   x loc y categ
             ULC(RL,RC) =0                                 ' unidades x loc y categ
             CCL#(RL,RC)=0                                 ' cancelac x loc y categ
             CUL(RL,RC) =0                                 ' canc uni x loc y categ
         NEXT RC
         AXL#(RC)=0                                        ' ajustes  x loc
         IVL#(RC)=0                                        ' iva      x loc
         CXL(RC)=0                                         ' cuentas  x loc
         NXL(RC)=0                                         ' notas    x loc
         PXL(RC)=0                                         ' personas x loc
     NEXT RL

     IQ=2:KI=0:KU=0:KT=0                                                  ' inicio en 2
1100 IF EOF(11) THEN 1350                                  ' termina
        COLOR 15,7:LOCATE PR+5,PC+15:PRINT USING "######";IQ
        GET#11,IQ                                          ' accesa archivo order1.que
        IF MID$(QUE11$,9,1)="1" THEN                       ' es venta
           GOSUB 1200                                      ' acumula venta
           GOSUB 2000                                      ' acumula mesero
           GOSUB 3000                                      ' acumula plu
           GOSUB 4000                                      ' acumula hora
           GOSUB 4200                                      ' acumula hora 2
           GOTO 1102
        ENDIF
        IF MID$(QUE11$,9,1)="0" THEN                       ' es cobro
           GOSUB 1300                                      ' acumula venta
           GOSUB 2100                                      ' acumula mesero
           GOSUB 4100                                      ' acumula hora
           GOTO 1102
        ENDIF
     IF MID$(QUE11$,9,1)<"0" THEN 1350                     ' fin de archivo
     IF MID$(QUE11$,9,1)>"9" THEN 1350                     ' fin de archivo
1102    IQ=IQ+1                                            ' incrementa contador
        GOTO 1100                                          ' regresa a accesar order.que

1110 CLOSE:END

1200                                                       ' ACUMULA VENTAS REG 1
     XLC=VAL(MID$(QUE11$,111,1)):IF XLC=0 THEN XLC=1       ' localizacion                            ' loc 1 si es 0
     XCA=VAL(MID$(QUE11$, 31,1)):IF XCA=0 THEN XCA=1       ' categoria
     IF MID$(QUE11$,30,1)="V" OR MID$(QUE11$,30,1)="v" THEN
        IF MID$(QUE11$,31,1)="9" THEN
           RETURN
        ELSE
           CCL#(XLC,XCA)=CCL#(XLC,XCA)+VAL(MID$(QUE11$,70,8)) ' acumula cancel venta
           CUL(XLC,XCA) =CUL(XLC,XCA) +VAL(MID$(QUE11$,61,8)) ' acumula cancel unidades
           RETURN                                             
        ENDIF
     ENDIF
     IF MID$(QUE11$,31,2)="94" THEN
        AXL#(XLC)=AXL#(XLC)+VAL(MID$(QUE11$,70,8))         ' acumula ajuste                  ' es plu de cobro
     ENDIF
     IF MID$(QUE11$,31,1)="9" THEN RETURN                  ' es cobro
        VLC#(XLC,XCA)=VLC#(XLC,XCA)+VAL(MID$(QUE11$,70,8)) ' acumula venta
        ULC(XLC,XCA) =ULC(XLC,XCA) +VAL(MID$(QUE11$,61,8)) ' acumula unidades
        RETURN

1300                                                       ' ACUMULA VENTAS REG 0
        XLC=VAL(MID$(QUE11$,111,1)):IF XLC=0 THEN XLC=1    ' localizacion
        IF VAL(MID$(QUE11$,46,8))<>0 THEN
           IVL#(XLC)=IVL#(XLC)+VAL(MID$(QUE11$,54,8))      ' acumula ajuste                  ' es plu de cobro
           CXL(XLC)=CXL(XLC)+1                             ' acumula cuenta
           NXL(XLC)=NXL(XLC)+VAL(MID$(QUE11$,27,1))        ' acumula notas
           IF VAL(MID$(QUE11$,28,2))=O THEN
              PXL(XLC)=PXL(XLC)+1                          ' acumula personas
           ELSE
              PXL(XLC)=PXL(XLC)+VAL(MID$(QUE11$,28,2))     ' acumula personas
           ENDIF
        ENDIF
        RETURN

1350                                                       ' GRABA VENTA - VTATOT.ARG
        GET#1,MESDIA                                       ' accesa #1 ventas totales
        LSET  F1$=CHR$(0)                                  ' status alta/baja
        VD$=VD1$                                           ' ventas        del dia
        VU$=VU1$                                           ' unidades      del dia
        AD$=AD1$                                           ' ajustes  x loc
        IV$=IV1$                                           ' ivas     x loc
        CA$=CI1$                                           ' cancel        del dia
        CU$=CU1$                                           ' cancel unid   del dia
        NC$=NC1$                                           ' cuentas  x loc
        NT$=NT1$                                           ' notas    x loc
        NP$=NP1$                                           ' personas x loc
        FOR RL=1 TO 9                                      ' localizaciones
            FOR RC=1 TO 8                                  ' categorias
                MID$(VD$,64*(RL-1)+8*(RC-1)+1,8)=MKD$(VLC#(RL,RC)) ' ventas   x loc y categ
                MID$(VU$,32*(RL-1)+4*(RC-1)+1,4)=MKS$(ULC(RL,RC))  ' unidades x loc y categ
                MID$(CA$,64*(RL-1)+8*(RC-1)+1,8)=MKD$(CCL#(RL,RC)) ' cancel   x loc y categ
                MID$(CU$,32*(RL-1)+4*(RC-1)+1,4)=MKS$(CUL(RL,RC))  ' canc uni x loc y categ
            NEXT RC
            MID$(AD$,8*(RL-1)+1,8)=MKD$(AXL#(RL))          ' ajustes  x loc 
            MID$(IV$,8*(RL-1)+1,8)=MKD$(IVL#(RL))          ' iva      x loc 
            MID$(NC$,2*(RL-1)+1,2)=MKI$(CXL(RL))           ' cuentas  x loc 
            MID$(NT$,2*(RL-1)+1,2)=MKI$(NXL(RL))           ' notas    x loc 
            MID$(NP$,2*(RL-1)+1,2)=MKI$(PXL(RL))           ' personas x loc 
        NEXT RL
        LSET VD1$=VD$                                      ' vector de ventas en importe
        LSET VU1$=VU$                                      ' vector de ventas en unidades
        LSET AD1$=AD$                                      ' vector de ajustes en importe
        LSET IV1$=IV$                                      ' vector de ivas   en importe
        LSET CI1$=CA$                                      ' vector de cancel en importe
        LSET CU1$=CU$                                      ' vector de cancel en unidades
        LSET NC1$=NC$                                      ' vector de cuentas
        LSET NT1$=NT$                                      ' vector de notas
        LSET NP1$=NP$                                      ' vector de personas
        PUT#1,MESDIA                                       ' graba

                                                           ' PARA PRUEBAS: INCLUIR: TSTARG.BAS
        CLOSE:END

2000                                                       ' ACUMULA VENTAS X MESERO REG 1
     GOSUB 2500                                            ' busca mesero RMSRO
     IF MID$(QUE11$,30,1)="V" OR MID$(QUE11$,30,1)="v" THEN
        IF MID$(QUE11$,31,1)="9" THEN
           RETURN
        ELSE
           CI$=CI2$                                        ' cancelaciones
           TT=CVS(MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4))
           CI=TT+VAL(MID$(QUE11$,70,8))                    ' acumula cancel venta
           MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CI)    ' reasigna
           CU$=CU2$                                        ' cancel en unidades
           TT=CVS(MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4))
           CU=TT+VAL(MID$(QUE11$,61,8))                    ' acumula cancel unidades
           MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CU)    ' reasigna
           LSET CI2$=CI$                                   ' cancelac importe
           LSET CU2$=CU$                                   ' cancel unidad
           PUT#2,RMSRO                                     ' graba
           RETURN
        ENDIF
     ENDIF
     IF MID$(QUE11$,31,1)="9" THEN RETURN                  ' es cobro
     VD$=VD2$                                              ' ventas del dia
     TT=CVS(MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4))
     VD=TT+VAL(MID$(QUE11$,70,8))                          ' acumula venta
     MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VD)          ' reasigna
     VU$=VU2$                                              ' ventas en unidades
     TT=CVS(MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4))
     VU=TT+VAL(MID$(QUE11$,61,8))                          ' acumula venta unidades
     MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VU)          ' reasigna
     LSET VD2$=VD$                                         ' venta diaria
     LSET VU2$=VU$                                         ' venta unidad
     PUT#2,RMSRO                                           ' graba
     RETURN

2100                                                       ' ACUMULA VENTAS X MESERO REG 0
     IF VAL(MID$(QUE11$,46,8))<>0 THEN
        GOSUB 2500                                         ' busca mesero RMSRO
        NC$=NC2$
        TT=CVI(MID$(NC$,62*(MES-1)+2*(DIA-1)+1,2))
        NC=TT+1                                            ' acumula cuentas
        MID$(NC$,62*(MES-1)+2*(DIA-1)+1,2)=MKI$(NC)        ' reasigna
        NP$=NP2$
        IF VAL(MID$(QUE11$,28,2))=0 THEN
           TT=CVI(MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2))
           NP=TT+1                                         ' acumula personas
        ELSE
           TT=CVI(MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2))
           NP=TT+VAL(MID$(QUE11$,28,2))                    ' acumula personas
        ENDIF
        MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2)=MKI$(NP)        ' reasigna
        LSET NC2$=NC$                                      ' cuentas
        LSET NP2$=NP$                                      ' personas
        LSET SN2$=MID$(QUE11$,30,6)+SPACE$(2)              ' nombre corto
        LSET CL2$=MID$(QUE11$,43,1)                        ' clasificacion
        PUT#2,RMSRO                                        ' graba
     ENDIF
     RETURN

2500 XME$=MID$(QUE11$,91,4)                                ' mesero
     FOR I=1 TO UM                                         ' busca mesero
         GET#2,I                                           ' accesa registro
         IF ASC(F2$)=0 THEN
            IF NU2$=XME$ THEN                              ' localizą mesero
               RMSRO=I
               RETURN               
            ENDIF
         ENDIF
     NEXT I
     IF UM+1>MM THEN
        CLS
        LOCATE 2,2:PRINT "NO HAY ESPACIO PARA MESEROS..."
        CLOSE:END
     ENDIF
     UM=UM+1                                               ' ultimo mesero
     RMSRO=UM                                              ' registro mesero
     GET#2,RMSRO                                           ' accesa registro
     LSET F2$=CHR$(0)                                      ' status alta
     LSET NU2$=XME$                                        ' numero
     PUT#2,RMSRO                                           ' alta mesero
     LSET UM5$=MKS$(UM)                                    ' ultimo mesero
     PUT#5,1                                               ' graba temporal
     RETURN

3000                                                       ' ACUMULA VENTAS X PLU REG 1
     GOSUB 3500                                            ' busca plu RPLU
     IF MID$(XPLU$,1,1)="9" THEN RETURN                    ' es cobro
     IF MID$(QUE11$,30,1)="V" OR MID$(QUE11$,30,1)="v" THEN
        CI$=CI3$                                           ' cancelaciones
        TT=CVS(MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4))
        CI=TT+VAL(MID$(QUE11$,70,8))                       ' acumula cancel venta
        MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CI)       ' reasigna
        CU$=CU3$                                           ' cancel en unidades
        TT=CVS(MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4))
        CU=TT+VAL(MID$(QUE11$,61,8))                       ' acumula cancel unidades
        MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CU)       ' reasigna
        LSET CI3$=CI$                                      ' cancelac importe
        LSET CU3$=CU$                                      ' cancel unidad
        IF MID$(QUE11$,29,1)="1" THEN
           LSET NC3$=MID$(QUE11$,37,8)                     ' nombre plu
        ENDIF
        PUT#3,RPLU                                            ' graba
        RETURN
     ENDIF
     VD$=VD3$                                              ' ventas del dia
     TT=CVS(MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4))
     VD=TT+VAL(MID$(QUE11$,70,8))                          ' acumula venta
     MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VD)          ' reasigna
     VU$=VU3$                                              ' ventas en unidades
     TT=CVS(MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4))
     VU=TT+VAL(MID$(QUE11$,61,8))                          ' acumula venta unidades
     MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VU)          ' reasigna
     LSET VD3$=VD$                                         ' venta diaria
     LSET VU3$=VU$                                         ' venta unidad
     IF MID$(QUE11$,29,1)="1" THEN
        LSET NC3$=MID$(QUE11$,37,8)                        ' nombre plu
     ENDIF
     PUT#3,RPLU                                            ' graba
     RETURN

3500 XPLU$=MID$(QUE11$,31,5)                               ' plu
     IF MID$(XPLU$,1,1)="9" THEN RETURN                    ' es cobro
     FOR I=1 TO UP                                         ' busca mesero
         GET#3,I                                           ' accesa registro
         IF ASC(F3$)=0 THEN
            IF PL3$=XPLU$ THEN                             ' localizą plu
               RPLU=I
               RETURN               
            ENDIF
         ENDIF
     NEXT I
     IF UP+1>MP THEN
        CLS
        LOCATE 2,2:PRINT "NO HAY ESPACIO PARA PLUS..."
        CLOSE:END
     ENDIF
     UP=UP+1                                               ' ultimo plu
     RPLU=UP                                               ' registro plu
     GET#3,RPLU                                            ' accesa registro
     LSET F3$=CHR$(0)                                      ' status alta
     LSET PL3$=XPLU$                                       ' numero
     IE=0:GOSUB 3600                                       ' busca nombre
     IF IE=1 THEN RETURN                                   ' no existe asc-b
        IF NOL$=SPACE$(24) THEN
           LSET NL3$=MID$(QUE11$,37,8)+SPACE$(16)
        ELSE
           LSET NL3$=NOL$
        ENDIF
        PUT#3,RPLU                                         ' alta plu
        LSET UP5$=MKS$(UP)                                 ' ultimo plu
        PUT#5,1                                            ' graba temporal
        RETURN

3600 OPEN "I",33,"ASC-B"
     NOL$=SPACE$(24)
     NOC$=SPACE$(08)
     IF IE=1    THEN CLOSE#33:RETURN
5615 IF EOF(33) THEN CLOSE#33:RETURN
     INPUT#33,X01$,X02$,X03$,X04$,X05$,X06$,X07$,X08$,X09$,X10$,X11$,X12$,X13$,X14$,X15$,X16$,X17$,X18$,X19$,X20$,X21$,X22$,X23$,X24$,X25$,X26$,X27$,X28$
     YPLU$=MID$(X02$,2,5)                                 ' plu
     IF XPLU$=YPLU$ THEN
        NOL$=MID$(X03$,2,24)                              ' nombre
        NOC$=MID$(X04$,2,08)                              ' corto
        CLOSE#33
        RETURN
     ENDIF
     GOTO 5615

4000                                                       ' ACUMULA VENTAS X HORA REG 1
     RHOR=VAL(MID$(QUE11$,5,2)):IF RHOR=0 THEN RHOR=24     ' hora                                           
     GET#4,RHOR
     IF MID$(QUE11$,30,1)="V" OR MID$(QUE11$,30,1)="v" THEN
        IF MID$(QUE11$,31,1)="9" THEN
           RETURN
        ELSE
           CI$=CI4$                                        ' cancelaciones
           TT=CVS(MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4))
           CI=TT+VAL(MID$(QUE11$,70,8))                    ' acumula cancel venta
           MID$(CI$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CI)    ' reasigna
           CU$=CU4$                                        ' cancel en unidades
           TT=CVS(MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4))
           CU=TT+VAL(MID$(QUE11$,61,8))                    ' acumula cancel unidades
           MID$(CU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(CU)    ' reasigna
           LSET CI4$=CI$                                   ' cancelac importe
           LSET CU4$=CU$                                   ' cancel unidad
           PUT#4,RHOR                                      ' graba
           RETURN
        ENDIF
     ENDIF
     IF MID$(QUE11$,31,1)="9" THEN RETURN                  ' es cobro
     VD$=VD4$                                              ' ventas del dia
     TT=CVS(MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4))
     VD=TT+VAL(MID$(QUE11$,70,8))                          ' acumula venta
     MID$(VD$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VD)          ' reasigna
     VU$=VU4$                                              ' ventas en unidades
     TT=CVS(MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4))
     VU=TT+VAL(MID$(QUE11$,61,8))                          ' acumula venta unidades
     MID$(VU$,124*(MES-1)+4*(DIA-1)+1,4)=MKS$(VU)          ' reasigna
     LSET VD4$=VD$                                         ' venta diaria
     LSET VU4$=VU$                                         ' venta unidad
     PUT#4,RHOR                                            ' graba
     RETURN

4100                                                       ' ACUMULA VENTAS X HORA REG 0
     IF VAL(MID$(QUE11$,46,8))<>0 THEN
        RHOR=VAL(MID$(QUE11$,5,2)):IF RHOR=0 THEN RHOR=24  ' hora                                            ' busca mesero RMSRO
        GET#4,RHOR
        NC$=NC4$                                           ' cuentas
        TT=CVI(MID$(NC$,62*(MES-1)+2*(DIA-1)+1,2))
        NC=TT+1                                            ' acumula cuentas
        MID$(NC$,62*(MES-1)+2*(DIA-1)+1,2)=MKI$(NC)        ' reasigna
        NP$=NP4$
        IF VAL(MID$(QUE11$,28,2))=0 THEN
           TT=CVI(MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2))
           NP=TT+1                                         ' acumula personas
        ELSE
           TT=CVI(MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2))
           NP=TT+VAL(MID$(QUE11$,28,2))                    ' acumula personas
        ENDIF
        MID$(NP$,62*(MES-1)+2*(DIA-1)+1,2)=MKI$(NP)        ' reasigna
        NT$=NT4$                                           ' cuentas
        TT=CVI(MID$(NT$,62*(MES-1)+2*(DIA-1)+1,2))
        NT=TT+VAL(MID$(QUE11$,27,1))                       ' acumula notas
        MID$(NT$,62*(MES-1)+2*(DIA-1)+1,2)=MKI$(NT)        ' reasigna
        LSET NC4$=NC$                                      ' cuentas
        LSET NP4$=NP$                                      ' personas
        LSET NT4$=NT$                                      ' notas
        PUT#4,RHOR                                         ' graba
     ENDIF
     RETURN

4200                                                       ' ACUMULA VENTAS X HORA 2 REG 1
     IF MID$(QUE11$,30,1)="V" OR MID$(QUE11$,30,1)="v" THEN RETURN ' es cancelacion
     IF MID$(QUE11$,31,1)="9" THEN RETURN                  ' es cobro
     RHOR=VAL(MID$(QUE11$,5,2)):IF RHOR=0 THEN RHOR=24     ' hora
     RHOR=372*(RHOR-1)+MESDIA                              ' registro hora
     GET#6,RHOR
     XLC=VAL(MID$(QUE11$,111,1)):IF XLC=0 THEN XLC=1       ' localizacion
     XCA=VAL(MID$(QUE11$,31,1)) :IF XCA=0 THEN XCA=1       ' categoria
     VDL$=VDL6$                                            ' ventas del dia             local
     VDL=CVS(MID$(VDL$,4*(XLC-1)+1,4))+VAL(MID$(QUE11$,70,8)) ' acumula venta           local
     MID$(VDL$,4*(XLC-1)+1,4)=MKS$(VDL)                    ' reasigna                   local
     VUL$=VUL6$                                            ' ventas del dia en unidades local
     VTA#=VAL(MID$(QUE11$,61,8))                           ' venta
     IF VTA#<0 OR VTA#>32767 THEN VTA#=0                   ' asigna 1
     VUL=CVI(MID$(VUL$,2*(XLC-1)+1,2))+VTA#                ' acumula venta              local
     MID$(VUL$,2*(XLC-1)+1,2)=MKI$(VUL)                    ' reasigna                   local
     VDC$=VDC6$                                            ' ventas del dia             categ
     VDC=CVS(MID$(VDC$,4*(XCA-1)+1,4))+VAL(MID$(QUE11$,70,8)) ' acumula venta           categ
     MID$(VDC$,4*(XCA-1)+1,4)=MKS$(VDC)                    ' reasigna                   categ
     VUC$=VUC6$                                            ' ventas del dia en unidades categ
     VTA#=VAL(MID$(QUE11$,61,8))
     IF VTA#<0 OR VTA#>32767 THEN VTA#=0                   ' asigna 1
     VUC=CVI(MID$(VUC$,2*(XCA-1)+1,2))+VTA#                ' acumula venta              categ
     MID$(VUC$,2*(XCA-1)+1,2)=MKI$(VUC)                    ' reasigna                   categ
     LSET VDL6$=VDL$                                       ' venta diaria local
     LSET VUL6$=VUL$                                       ' venta unidad local
     LSET VDC6$=VDC$                                       ' venta diaria categ
     LSET VUC6$=VUC$                                       ' venta unidad categ
     PUT#6,RHOR                                            ' graba
     RETURN

6999 ' $INCLUDE: 'R40GRL.BAS'
